Alles Voor Internet / Tout Pour Internet/alles voor internet.iso/MacInternet™/Modem/Annex Map/Annex-Mark.Verber

Text File | 1993-10-18 | 2KB | 105 lines

! Newsgroups: comp.sys.mac.comm
! From: [e-mail] (Mark Verber)
! Subject: Re: SLIP on a Xylogics Annex
! Organization: Xerox PARC, Palo Alto, CA
! Date: 18 Oct 93 10:52:57
!
! [...stuff deleted...]
!
! I haven't had any trouble with InterSLIP since the bug fixes that
! let you match on an IP address and then set the Macs address.  Here
! is a basic annex gateway script I hacked together.  It is not pretty,
! but I has worked without failing.  I have been meaning to clean this
! script up but I haven't gotten around to it.
!
! InterSLIP gateway script for Annex terminal server which has been
! configured to give users a command line interface to the terminal server.
!
! Mark Verber <[e-mail]>
! Xerox Palo Alto Research Center (PARC)
!
settries 0
note "Giving the annex a second.."
pause 30
!
! Most Annex terminal servers give a "Annex username:" prompt.  Some do a
! "MachineName username:" so we look for "username".  Change this if your
! annex says "login:"
!
@label 0
note "Sending <cr> looking for username..."
write "\13"
matchstr 1 1 "username:"
matchread 60
note "Trying again ..."
inctries
iftries 6 99
jump 0
!
@label 1
note "Sending username"
write "^5\13"
matchclr
matchstr 1 2 "password:"
matchread 120
note "Gateway not responding!"
jump 99
!
@label 2
note "Sending password"
write "^6\13"
matchclr
matchstr 1 3 "Username/Password Incorrect"
matchstr 2 4 "Permission granted"
matchread 240
jump 99
!
@label 3
note "Access Denied, bad password?"
jump 99
!
@label 4
!
! The annex prompt will vary machine to machine.  Looking
! for ":" the only thing you know will be on each prompt is
! to risky.
!
note "Waiting for annex prompt..."
matchclr
matchstr 1 5 "annex2:"
matchread 240
jump 99
!
@label 5
note "Sending slip command"
write "slip\13"
matchclr
matchstr 1 6 "Your address"
matchread 240
jump 99
!
@label 6
note "Waiting for your address..."
matchclr
matchexp 1 7 "[0-9]*\\.[0-9]*\\.[0-9]*\\.[0-9]*"
matchread 60
jump 99
!
@label 7
note "Your address ^0"
setip "^0"
setmtu "1006"
pause 60
exit 0
!
! currently unused:
!
@answer
@hangup
exit 0
!
!
@label 99
sound Indigo
pause 60
exit -1